[new package] rust-bindgen 0.70.1

mingw-w64-rust-bindgen/PKGBUILD

@@ -0,0 +1,55 @@
+# Maintainer: Konstantin Podsvirov <konstantin@podsvirov.pro>
+
+_realname=rust-bindgen
+pkgbase=mingw-w64-${_realname}
+pkgname="${MINGW_PACKAGE_PREFIX}-${_realname}"
+pkgver=0.70.1
+pkgrel=1
+pkgdesc='Automatically generates Rust FFI bindings to C (and some C++) libraries (mingw-w64)'
+arch=('any')
+mingw_arch=('ucrt64' 'clang64' 'clangarm64')
+url='https://rust-lang.github.io/rust-bindgen/'
+msys2_repository_url='https://github.com/rust-lang/rust-bindgen'
+msys2_references=(
+  'archlinux: rust-bindgen'
+)
+license=('spdx:BSD-3-Clause')
+depends=("${MINGW_PACKAGE_PREFIX}-clang" "${MINGW_PACKAGE_PREFIX}-gcc-libs")
+makedepends=("${MINGW_PACKAGE_PREFIX}-rust"
+             "${MINGW_PACKAGE_PREFIX}-mdbook")
+source=("${msys2_repository_url}/archive/v${pkgver}/${_realname}-${pkgver}.tar.gz")
+sha256sums=('243ed50f99c00ae8c18d50429a1278b6fd37dff94df46df38f2733745362c014')
+
+prepare() {
+  cd "${srcdir}/${_realname}-${pkgver}"
+
+  cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
+}
+
+build() {
+  cd "${srcdir}/${_realname}-${pkgver}"
+
+  "${MINGW_PREFIX}/bin/cargo.exe" build \
+    --release \
+    --frozen
+
+  cd book
+  "${MINGW_PREFIX}/bin/mdbook.exe" build
+}
+
+check() {
+  cd "${srcdir}/${_realname}-${pkgver}"
+
+  "${MINGW_PREFIX}/bin/cargo.exe" test \
+    --release \
+    --locked
+}
+
+package() {
+  cd "${srcdir}/${_realname}-${pkgver}"
+
+  install -Dm755 "target/release/bindgen.exe" "${pkgdir}${MINGW_PREFIX}/bin/bindgen.exe"
+  install -d "${pkgdir}${MINGW_PREFIX}/share/doc/${_realname}"
+  cp -a "book/book" "${pkgdir}${MINGW_PREFIX}/share/doc/${_realname}/html"
+  install -Dm644 "LICENSE" "${pkgdir}${MINGW_PREFIX}/share/licenses/${_realname}/LICENSE"
+}