tree-sitter-markdown: update to 0.5.0

mingw-w64-tree-sitter-markdown/PKGBUILD

@@ -2,9 +2,9 @@
 _realname=tree-sitter-markdown
 pkgbase=mingw-w64-${_realname}
 pkgname=("${MINGW_PACKAGE_PREFIX}-${_realname}")
-pkgver=0.3.2
+pkgver=0.5.0
 pkgrel=1
-pkgdesc='Markdown grammar for tree-sitter (mingw-64)'
+pkgdesc='Markdown grammar for tree-sitter (mingw-w64)'
 arch=('any')
 mingw_arch=('ucrt64' 'clang64' 'clangarm64')
 url='https://github.com/tree-sitter-grammars/tree-sitter-markdown'
@@ -15,34 +15,42 @@ msys2_references=(
 license=('spdx:MIT')
 makedepends=(
   "${MINGW_PACKAGE_PREFIX}-cc"
+  "${MINGW_PACKAGE_PREFIX}-cmake"
   "${MINGW_PACKAGE_PREFIX}-tree-sitter"
+  "${MINGW_PACKAGE_PREFIX}-nodejs"
 )
 source=("https://github.com/tree-sitter-grammars/${_realname}/archive/v${pkgver}/${_realname}-${pkgver}.tar.gz")
-sha256sums=('5dac48a6d971eb545aab665d59a18180d21963afc781bbf40f9077c06cb82ae5')
+sha256sums=('14c2c948ccf0e9b606eec39b09286c59dddf28307849f71b7ce2b1d1ef06937e')
 
 prepare() {
-  cd "${srcdir}/${_realname}-${pkgver}/tree-sitter-markdown"
-  tree-sitter generate --no-bindings src/grammar.json
+  cd "${_realname}-${pkgver}/tree-sitter-markdown"
+  tree-sitter generate src/grammar.json
 
   cd "../tree-sitter-markdown-inline"
-  tree-sitter generate --no-bindings src/grammar.json
+  tree-sitter generate src/grammar.json
 }
 
 build() {
-  cd "${srcdir}/${_realname}-${pkgver}"
-  # To get around Windows not being supported
-  OS='unknown' make CC='cc' LINKSHARED='-shared' PREFIX="${MINGW_PREFIX}" PARSER_URL=$url
+  MSYS2_ARG_CONV_EXCL="-DCMAKE_INSTALL_PREFIX" \
+    cmake \
+      -DCMAKE_INSTALL_PREFIX="${MINGW_PREFIX}" \
+      -Wno-dev \
+      -DCMAKE_BUILD_TYPE=None \
+      -DCMAKE_SHARED_LIBRARY_SUFFIX_C=.so \
+      -DCMAKE_INSTALL_BINDIR=lib \
+      -S "${_realname}-${pkgver}" \
+      -B "build-${MSYSTEM}"
+
+  cmake --build "build-${MSYSTEM}"
 }
 
 package() {
-  install -d "${pkgdir}${MINGW_PREFIX}/lib/tree_sitter"
-  cd "${srcdir}/${_realname}-${pkgver}"
-  OS='unknown' make DESTDIR="${pkgdir}" PREFIX="${MINGW_PREFIX}" install
+  DESTDIR="${pkgdir}" cmake --install "build-${MSYSTEM}"
 
   # To add library to neovim runtime path
   mkdir -p "${pkgdir}${MINGW_PREFIX}/lib/nvim/parser"
   cp "${pkgdir}${MINGW_PREFIX}/lib/lib${_realname}.so" "${pkgdir}${MINGW_PREFIX}/lib/nvim/parser/${_realname#tree-sitter-}.so"
   cp "${pkgdir}${MINGW_PREFIX}/lib/lib${_realname}-inline.so" "${pkgdir}${MINGW_PREFIX}/lib/nvim/parser/${_realname#tree-sitter-}_inline.so"
 
-  install -Dm644 LICENSE "${pkgdir}${MINGW_PREFIX}/share/licenses/${_realname}/LICENSE"
+  install -Dm644 "${_realname}-${pkgver}"/LICENSE "${pkgdir}${MINGW_PREFIX}/share/licenses/${_realname}/LICENSE"
 }