Add python-pyproject-hooks

replacement for pep517

mingw-w64-python-pyproject-hooks/PKGBUILD

@@ -0,0 +1,45 @@
+# Maintainer: Christoph Reiter <reiter.christoph@gmail.com>
+
+_pyname=pyproject_hooks
+_realname=pyproject-hooks
+pkgbase=mingw-w64-python-${_realname}
+pkgname=("${MINGW_PACKAGE_PREFIX}-python-${_realname}")
+pkgver=1.0.0
+pkgrel=1
+pkgdesc="A low-level library for calling build-backends in pyproject.toml-based project (mingw-w64)"
+arch=('any')
+mingw_arch=('mingw32' 'mingw64' 'ucrt64' 'clang64' 'clang32' 'clangarm64')
+url='https://github.com/pypa/pyproject-hooks'
+license=('spdx:MIT')
+depends=(
+  "${MINGW_PACKAGE_PREFIX}-python"
+  "${MINGW_PACKAGE_PREFIX}-python-tomli"
+)
+makedepends=(
+  "${MINGW_PACKAGE_PREFIX}-python-flit-core"
+  "${MINGW_PACKAGE_PREFIX}-python-installer"
+)
+source=("https://pypi.org/packages/source/${_pyname::1}/${_pyname}/${_pyname}-${pkgver}.tar.gz")
+sha256sums=('f271b298b97f5955d53fb12b72c1fb1948c22c1a6b70b315c54cedaca0264ef5')
+
+prepare() {
+  cd "${srcdir}/${_pyname}-${pkgver}"
+
+}
+
+build() {
+  cd "${srcdir}"
+  cp -r "${_pyname}-${pkgver}" "python-build-${MSYSTEM}" && cd "python-build-${MSYSTEM}"
+
+  python -m flit_core.wheel
+}
+
+package() {
+  cd "${srcdir}/python-build-${MSYSTEM}"
+
+  MSYS2_ARG_CONV_EXCL="--prefix=" \
+    python -m installer --prefix=${MINGW_PREFIX} \
+    --destdir="${pkgdir}" dist/*.whl
+
+  install -Dm644 LICENSE "${pkgdir}${MINGW_PREFIX}/share/licenses/python-${_realname}/LICENSE"
+}