alure (#3292)

mingw-w64-alure/PKGBUILD

@@ -0,0 +1,56 @@
+# Maintainer: Greg Williamson <cheeseboy16@gmail.com>
+
+_realname=alure
+pkgbase="mingw-w64-${_realname}"
+pkgname="${MINGW_PACKAGE_PREFIX}-${_realname}"
+pkgver=1.2
+pkgrel=5
+pkgdesc='Utility library to help manage common tasks with OpenAL applications (mingw-w64)'
+arch=('any')
+url='http://kcat.strangesoft.net/alure.html'
+license=('MIT')
+depends=("${MINGW_PACKAGE_PREFIX}-openal")
+makedepends=("${MINGW_PACKAGE_PREFIX}-cmake" 
+             "${MINGW_PACKAGE_PREFIX}-libsndfile" 
+             "${MINGW_PACKAGE_PREFIX}-libvorbis" 
+             "${MINGW_PACKAGE_PREFIX}-flac" 
+             "${MINGW_PACKAGE_PREFIX}-mpg123" 
+             "${MINGW_PACKAGE_PREFIX}-dumb" 
+             "${MINGW_PACKAGE_PREFIX}-fluidsynth")
+optdepends=("${MINGW_PACKAGE_PREFIX}-libsndfile: for uncompressed audio support"
+            "${MINGW_PACKAGE_PREFIX}-libvorbis: for OGG Vorbis support"
+            "${MINGW_PACKAGE_PREFIX}-flac: for FLAC support"
+            "${MINGW_PACKAGE_PREFIX}-mpg123: for MPEG support"
+            "${MINGW_PACKAGE_PREFIX}-dumb: for IT, XM, S3M and MOD support"
+            "${MINGW_PACKAGE_PREFIX}-fluidsynth: for SoundFont 2 support")
+source=("http://kcat.strangesoft.net/alure-releases/${_realname}-${pkgver}.tar.bz2"
+        build.patch)
+md5sums=('3088aba074ad02d95ea51e705053b9f5'
+         '6a8dfd62ccae920d393b4202736aba46')
+
+prepare() {
+  cd "${srcdir}/${_realname}-${pkgver}"
+  patch -p1 -i "${srcdir}/build.patch"
+}
+
+build() {
+  [[ -d "${srcdir}/build-${MINGW_CHOST}" ]] && rm -rf "${srcdir}/build-${MINGW_CHOST}"
+  mkdir -p "${srcdir}/build-${MINGW_CHOST}"
+  cd "${srcdir}/build-${MINGW_CHOST}"
+
+  MSYS2_ARG_CONV_EXCL="-DCMAKE_INSTALL_PREFIX=" \
+  ${MINGW_PREFIX}/bin/cmake \
+    -G "MSYS Makefiles" \
+    -DCMAKE_INSTALL_PREFIX="${MINGW_PREFIX}" \
+    ../${_realname}-${pkgver}
+  
+  make
+}
+
+package() {
+  cd "${srcdir}/build-${MINGW_CHOST}"
+
+  make DESTDIR="${pkgdir}" install
+
+  install -Dm0644 "${srcdir}/${_realname}-${pkgver}/COPYING" "${pkgdir}${MINGW_PREFIX}/share/licenses/${_realname}/LICENSE"
+}

mingw-w64-alure/build.patch

@@ -0,0 +1,12 @@
+diff -rupN a/src/codec_fluidsynth.cpp b/src/codec_fluidsynth.cpp
+--- a/src/codec_fluidsynth.cpp	2011-07-29 08:37:48.000000000 +0000
++++ b/src/codec_fluidsynth.cpp	2014-01-03 10:42:13.280792235 +0000
+@@ -32,7 +32,7 @@
+ #endif
+ 
+ #include <istream>
+-
++#include <unistd.h>
+ #include <fluidsynth.h>
+ 
+