directxmesh: Add package

mingw-w64-directxmesh/PKGBUILD

@@ -0,0 +1,53 @@
+# Maintainer: J. Peter Mugaas <jpmugaas@suddenlink.net>
+
+_realname=directxmesh
+_rn=DirectXMesh
+pkgbase=mingw-w64-${_realname}
+pkgname=("${MINGW_PACKAGE_PREFIX}-${_realname}")
+# Version from CMakeLists.txt
+pkgver=1.6.5
+_tag=dec2023
+pkgrel=1
+pkgdesc="DirectXMath is an all inline SIMD C++ linear algebra library for use in games and graphics apps (mingw-w64)"
+arch=('any')
+mingw_arch=('mingw32' 'mingw64' 'ucrt64' 'clang64' 'clang32')
+url='http://go.microsoft.com/fwlink/?LinkID=324981'
+license=('spdx:MIT')
+makedepends=("${MINGW_PACKAGE_PREFIX}-cmake"
+             "${MINGW_PACKAGE_PREFIX}-ninja"
+             "${MINGW_PACKAGE_PREFIX}-cc")
+depends=("${MINGW_PACKAGE_PREFIX}-directxmath"
+         "${MINGW_PACKAGE_PREFIX}-directx-headers")
+source=("${_realname}-${_tag}.tar.gz"::"https://github.com/microsoft/DirectXMesh/archive/refs/tags/${_tag}.tar.gz")
+sha256sums=('ee155583a1302b58311857c45577b4de2001dd1647c4161594888ef6149713f9')
+
+build() {
+  cd "${srcdir}/${_realname}-${_tag}"
+  mkdir -p "${srcdir}/build-${MSYSTEM}" && cd "${srcdir}/build-${MSYSTEM}"
+
+  declare -a extra_config
+  if check_option "debug" "n"; then
+    extra_config+=("-DCMAKE_BUILD_TYPE=Release")
+  else
+    extra_config+=("-DCMAKE_BUILD_TYPE=Debug")
+  fi
+
+  MSYS2_ARG_CONV_EXCL="-DCMAKE_INSTALL_PREFIX=" \
+    "${MINGW_PREFIX}"/bin/cmake.exe \
+      -GNinja \
+      -DCMAKE_INSTALL_PREFIX="${MINGW_PREFIX}" \
+      "${extra_config[@]}" \
+      -DBUILD_TOOLS=OFF \
+      -DBUILD_DX12=ON \
+      ../${_realname}-${_tag}
+
+  "${MINGW_PREFIX}"/bin/cmake.exe --build .
+}
+
+package() {
+  cd "${srcdir}/build-${MSYSTEM}"
+
+  DESTDIR="${pkgdir}" "${MINGW_PREFIX}"/bin/cmake.exe --install .
+
+  install -Dm644 "${srcdir}/${_realname}-${_tag}/LICENSE" "${pkgdir}${MINGW_PREFIX}/share/licenses/${_realname}/LICENSE"
+}