cargo-generate: New package

mingw-w64-cargo-generate/PKGBUILD

@@ -0,0 +1,59 @@
+# Maintainer: Konstantin Podsvirov <konstantin@podsvirov.pro>
+
+_realname=cargo-generate
+pkgbase=mingw-w64-${_realname}
+pkgname="${MINGW_PACKAGE_PREFIX}-${_realname}"
+pkgver=0.18.1
+pkgrel=1
+pkgdesc="Use pre-existing git repositories as templates (mingw-w64)"
+arch=('any')
+mingw_arch=('mingw32' 'mingw64' 'ucrt64' 'clang64' 'clang32')
+url="https://github.com/cargo-generate/cargo-generate"
+license=('MIT' 'Apache')
+makedepends=("${MINGW_PACKAGE_PREFIX}-rust"
+             "${MINGW_PACKAGE_PREFIX}-mdbook")
+options=('staticlibs' 'strip')
+source=("$_realname-$pkgver.tar.gz::$url/archive/v$pkgver.tar.gz")
+sha256sums=('3583b78c944e0c1a165a93e88b75c674e96874272a4104d487d0a035bbfeb401')
+
+prepare() {
+  cd "${srcdir}"
+  rm -rf "build-${MSYSTEM}" | true
+  cp -r "${_realname}-${pkgver}" "build-${MSYSTEM}"
+  cd "${srcdir}/build-${MSYSTEM}"
+
+  "${MINGW_PREFIX}/bin/cargo.exe" fetch
+}
+
+build() {
+  msg "Cargo build for ${MSYSTEM}"
+  cd "${srcdir}/build-${MSYSTEM}"
+
+  "${MINGW_PREFIX}/bin/cargo.exe" build \
+    --release \
+    --locked
+
+  msg "Build documentation"
+  cd guide
+
+  "${MINGW_PREFIX}/bin/mdbook.exe" build
+}
+
+check() {
+  cd "${srcdir}/build-${MSYSTEM}"
+
+  "${MINGW_PREFIX}/bin/cargo.exe" test \
+    --release \
+    --locked
+}
+
+package() {
+  cd "${srcdir}/build-${MSYSTEM}"
+
+  install -Dm755 "target/release/${_realname}.exe" "${pkgdir}${MINGW_PREFIX}/bin/${_realname}.exe"
+  install -d "${pkgdir}${MINGW_PREFIX}/share/doc/${_realname}"
+  cp -a "guide/book" "${pkgdir}${MINGW_PREFIX}/share/doc/${_realname}/html"
+  install -Dm644 "LICENSE-MIT" "${pkgdir}${MINGW_PREFIX}/share/licenses/${_realname}/LICENSE-MIT"
+  install -Dm644 "LICENSE-APACHE" "${pkgdir}${MINGW_PREFIX}/share/licenses/${_realname}/LICENSE-APACHE"
+}
+