gsutil

mingw-w64-python-gsutil/PKGBUILD

@@ -0,0 +1,39 @@
+# Maintainer: Sarah Ottinger
+
+_realname=gsutil
+pkgbase=mingw-w64-python-${_realname}
+pkgname=("${MINGW_PACKAGE_PREFIX}-python-${_realname}")
+provides=("${MINGW_PACKAGE_PREFIX}-python3-${_realname}")
+conflicts=("${MINGW_PACKAGE_PREFIX}-python3-${_realname}")
+replaces=("${MINGW_PACKAGE_PREFIX}-python3-${_realname}")
+pkgver=4.52
+pkgrel=1
+pkgdesc='A command line tool for interacting with cloud storage services. (mingw-w64)'
+arch=('any')
+url="https://cloud.google.com/storage/docs/gsutil"
+license=('Apache')
+depends=("${MINGW_PACKAGE_PREFIX}-python")
+makedepends=("${MINGW_PACKAGE_PREFIX}-python-setuptools")
+options=('!emptydirs')
+source=("https://github.com/GoogleCloudPlatform/gsutil/archive/v$pkgver.tar.gz")
+sha256sums=('2e2439817cda800eaf029974cae78ec10a2b03dbb1d3a3d0cd9ab0b631161207')
+
+prepare() {  
+  cd "$srcdir"
+  rm -rf python-build-${CARCH} | true
+  cp -r "${_realname}-${pkgver}" "python-build-${CARCH}"
+}
+
+build() {
+  msg "Python build for ${CARCH}"  
+  cd "${srcdir}/python-build-${CARCH}"
+  ${MINGW_PREFIX}/bin/python setup.py build
+}
+
+package() {
+  cd "${srcdir}/python-build-${CARCH}"
+  MSYS2_ARG_CONV_EXCL="--prefix=;--install-scripts=;--install-platlib=" \
+  ${MINGW_PREFIX}/bin/python setup.py install --prefix=${MINGW_PREFIX} \
+    --root="${pkgdir}" --optimize=1 --skip-build
+  install -Dm644 LICENSE "${pkgdir}${MINGW_PREFIX}/share/licenses/python-${_realname}/LICENSE"
+}