libmikmod: New package.

mingw-w64-libmikmod/PKGBUILD

@@ -0,0 +1,52 @@
+# Maintainer: Alexey Pavlov <alexpux@gmail.com>
+
+_realname=libmikmod
+pkgbase=mingw-w64-${_realname}
+pkgname="${MINGW_PACKAGE_PREFIX}-${_realname}"
+pkgver=3.3.7
+pkgrel=1
+pkgdesc="A portable sound library (mingw-w64)"
+arch=('any')
+url="http://mikmod.sourceforge.net"
+license=("GPL" "LGPL")
+makedepends=("${MINGW_PACKAGE_PREFIX}-gcc"
+             "${MINGW_PACKAGE_PREFIX}-pkg-config"
+             #"${MINGW_PACKAGE_PREFIX}-SDL"
+             #"${MINGW_PACKAGE_PREFIX}-SDL2"
+             "${MINGW_PACKAGE_PREFIX}-openal")
+depends=("${MINGW_PACKAGE_PREFIX}-gcc-libs")
+options=('strip' 'staticlibs')
+source=(http://downloads.sourceforge.net/mikmod/${_realname}-${pkgver}.tar.gz)
+sha256sums=('4cf41040a9af99cb960580210ba900c0a519f73ab97b503c780e82428b9bd9a2')
+
+build() {
+  export lt_cv_deplibs_check_method='pass_all'
+  [[ -d "build-${MINGW_CHOST}" ]] && rm -rf "build-${MINGW_CHOST}"
+  mkdir -p "${srcdir}/build-${MINGW_CHOST}"
+  cd "${srcdir}/build-${MINGW_CHOST}"
+  ../${_realname}-${pkgver}/configure \
+    --prefix=${MINGW_PREFIX} \
+    --build=${MINGW_CHOST} \
+    --host=${MINGW_CHOST} \
+    --target=${MINGW_CHOST} \
+    --enable-shared \
+    --enable-static \
+    --disable-sdl \
+    --disable-sdl2 \
+    --enable-openal
+
+  make
+}
+
+package() {
+  cd "${srcdir}/build-${MINGW_CHOST}"
+  make DESTDIR="${pkgdir}" install
+
+  # Install license
+  install -Dm644 ${srcdir}/${_realname}-${pkgver}/COPYING.LIB ${pkgdir}${MINGW_PREFIX}/share/licenses/${_realname}/COPYING.LIB
+  install -Dm644 ${srcdir}/${_realname}-${pkgver}/COPYING.LESSER ${pkgdir}${MINGW_PREFIX}/share/licenses/${_realname}/COPYING.LESSER
+  
+  local PREFIX_WIN=$(cygpath -m ${MINGW_PREFIX})
+  sed -s "s|${PREFIX_WIN}|${MINGW_PREFIX}|g" \
+    -i ${pkgdir}${MINGW_PREFIX}/bin/libmikmod-config
+}