Merge pull request #9832 from raedrizqie/python-nest-asyncio

New package: python-nest-asyncio

mingw-w64-python-nest-asyncio/PKGBUILD

@@ -0,0 +1,39 @@
+# Contributor: Raed Rizqie <raed.rizqie@gmail.com>
+
+_realname=nest-asyncio
+pkgbase=mingw-w64-python-${_realname}
+pkgname=${MINGW_PACKAGE_PREFIX}-python-${_realname}
+pkgver=1.5.1
+pkgrel=1
+pkgdesc='Patch asyncio to allow nested event loops (mingw-w64)'
+arch=('any')
+mingw_arch=('mingw32' 'mingw64' 'ucrt64' 'clang64' 'clang32')
+license=('BSD')
+url='https://github.com/erdewit/nest_asyncio'
+depends=(
+    ${MINGW_PACKAGE_PREFIX}-python)
+makedepends=(
+    ${MINGW_PACKAGE_PREFIX}-python-setuptools)
+source=(https://github.com/erdewit/nest_asyncio/archive/v${pkgver}.tar.gz)
+sha256sums=('d607e3b5a7f695a6927323ad32f67e95488f9a5bbf8f658a6fd72a745b084cce')
+
+prepare() {
+  cd "${srcdir}"
+  rm -rf python-build-${CARCH} | true
+  cp -r "nest_asyncio-${pkgver}" "python-build-${CARCH}"
+}
+
+build() {
+  msg "Python build for ${CARCH}"
+  cd "${srcdir}/python-build-${CARCH}"
+  ${MINGW_PREFIX}/bin/python setup.py build
+}
+
+package() {
+  cd "${srcdir}/python-build-${CARCH}"
+  MSYS2_ARG_CONV_EXCL="--prefix=;--install-scripts=;--install-platlib=" \
+  ${MINGW_PREFIX}/bin/python setup.py install --prefix=${MINGW_PREFIX} \
+    --root="${pkgdir}" --optimize=1 --skip-build
+
+  install -Dm644 LICENSE "${pkgdir}${MINGW_PREFIX}/share/licenses/python-${_realname}/LICENSE"
+}