svt-av1: new package

mingw-w64-svt-av1/PKGBUILD

@@ -0,0 +1,54 @@
+# Maintainer: Miloš Komarčević <miloskomarcevic@aim.com>
+
+_realname=SVT-AV1
+pkgbase=mingw-w64-svt-av1
+pkgname=("${MINGW_PACKAGE_PREFIX}-svt-av1")
+pkgver=0.8.7
+pkgrel=1
+pkgdesc="Scalable Video Technology AV1 encoder and decoder (mingw-w64)"
+arch=('any')
+mingw_arch=('mingw64' 'ucrt64' 'clang64')
+url='https://gitlab.com/AOMediaCodec/SVT-AV1'
+license=('AOM')
+depends=("${MINGW_PACKAGE_PREFIX}-crt")
+makedepends=("${MINGW_PACKAGE_PREFIX}-cmake"
+             "${MINGW_PACKAGE_PREFIX}-ninja"
+             "${MINGW_PACKAGE_PREFIX}-yasm")
+source=("${url}/-/archive/v${pkgver}/${_realname}-v${pkgver}.tar.gz")
+sha256sums=('de24e4a6c557498b2e8caf9cca438411db5f837d232b9390dc3899d974fec16f')
+
+prepare() {
+  cd "${srcdir}"/${_realname}-v${pkgver}
+}
+
+build() {
+  [[ -d "${srcdir}"/build-${CARCH} ]] && rm -rf "${srcdir}"/build-${CARCH}
+  mkdir -p "${srcdir}"/build-${CARCH} && cd "${srcdir}"/build-${CARCH}
+
+  declare -a extra_config
+  if check_option "debug" "n"; then
+    extra_config+=("-DCMAKE_BUILD_TYPE=Release")
+  else
+    extra_config+=("-DCMAKE_BUILD_TYPE=Debug")
+  fi
+
+  MSYS2_ARG_CONV_EXCL="-DCMAKE_INSTALL_PREFIX=" \
+    ${MINGW_PREFIX}/bin/cmake \
+      -GNinja \
+      -DCMAKE_INSTALL_PREFIX=${MINGW_PREFIX} \
+      "${extra_config[@]}" \
+      -DBUILD_SHARED_LIBS=ON \
+      -DREPRODUCIBLE_BUILDS=ON \
+      ../${_realname}-v${pkgver}
+
+  ${MINGW_PREFIX}/bin/cmake --build .
+}
+
+package() {
+  cd "${srcdir}"/build-${CARCH}
+
+  DESTDIR="${pkgdir}" ${MINGW_PREFIX}/bin/cmake --build . --target install
+
+  install -Dm644 ${srcdir}/${_realname}-v${pkgver}/LICENSE.md ${pkgdir}${MINGW_PREFIX}/share/licenses/svt-av1/LICENSE.md
+  install -Dm644 ${srcdir}/${_realname}-v${pkgver}/PATENTS.md ${pkgdir}${MINGW_PREFIX}/share/licenses/svt-av1/PATENTS.md
+}