grml-zsh-config: New package.

grml-zsh-config/PKGBUILD

@@ -0,0 +1,32 @@
+# Maintainer: Norbert Pfeiler <norbert.pfeiler+aur ät gmail.com>
+
+pkgname=grml-zsh-config
+pkgver=0.12.6
+pkgrel=1
+pkgdesc="grml's zsh setup"
+arch=('any')
+url='http://grml.org/zsh/'
+license=('GPL2')
+provides=('grmlzshrc')
+depends=('zsh' 'coreutils' 'inetutils' 'grep' 'sed' 'procps')
+makedepends=('txt2tags')
+source=("http://deb.grml.org/pool/main/g/grml-etc-core/grml-etc-core_${pkgver}.tar.gz")
+sha256sums=('8b712099b812f1d07429bfe4c19b45b9b1efd1c173c1be8f49c6351edcd1a118')
+
+build() {
+  cd ${srcdir}/grml-etc-core-${pkgver}/doc
+  make
+}
+
+package() {
+  cd ${srcdir}/grml-etc-core-${pkgver}
+  install -D -m644 etc/skel/.zshrc ${pkgdir}/etc/skel/.zshrc
+  install -D -m644 etc/zsh/keephack ${pkgdir}/etc/zsh/keephack
+  install -D -m644 etc/zsh/zshrc ${pkgdir}/etc/zsh/zshrc
+
+  install -D -m644 doc/grmlzshrc.5 ${pkgdir}/usr/share/man/man5/grmlzshrc.5
+  # the symlinking from the original pkg doesn’t work
+  # because the target doesn’t exist yet (manpage compression)
+  # and msys2’s symlink simply copies
+  install -D -m644 doc/grmlzshrc.5 ${pkgdir}/usr/share/man/man5/grml-zsh-config.5
+}