dnslookup: Add package

mingw-w64-dnslookup/PKGBUILD

@@ -0,0 +1,43 @@
+# Maintainer: @naveen521kk on Github <naveen521kk@gmail.com>
+
+_realname=dnslookup
+pkgbase=mingw-w64-${_realname}
+pkgname=("${MINGW_PACKAGE_PREFIX}-${_realname}")
+pkgver=1.5.1
+pkgrel=1
+pkgdesc='Simple command line utility to make DNS lookups (mingw-w64)'
+arch=('any')
+mingw_arch=('mingw32' 'mingw64' 'ucrt64' 'clang64')
+url="https://github.com/ameshkov/dnslookup"
+license=('MIT')
+makedepends=("${MINGW_PACKAGE_PREFIX}-go" "${MINGW_PACKAGE_PREFIX}-cc")
+checkdepends=("git")
+optdepends=("git: To interact with repositories")
+options=('!strip')
+source=("$_realname-$pkgver.tar.gz::$url/archive/v$pkgver.tar.gz")
+sha256sums=('b09fc07d917cfe3d5b08bdf2e92aa9ee63928d86e3477724656dae5a50683c45')
+build() {
+    cd "${_realname}-$pkgver"
+    export GOOS=windows
+    export GOROOT=${MINGW_PREFIX}/lib/go
+    export CGO_CPPFLAGS="${CPPFLAGS}"
+    export CGO_CFLAGS="${CFLAGS}"
+    export CGO_CXXFLAGS="${CXXFLAGS}"
+    export CGO_LDFLAGS="${LDFLAGS}"
+    export GO_LDFLAGS="-s -w"
+    export GOFLAGS="-trimpath -mod=readonly -modcacherw -ldflags=-linkmode=external"
+
+    make VERSION=$pkgver build
+}
+
+check(){
+    cd "${_realname}-$pkgver"
+    make test
+}
+
+package() {
+    cd "${_realname}-$pkgver"
+    install -Dm755 "dnslookup.exe" "${pkgdir}${MINGW_PREFIX}/bin/dnslookup.exe"
+    install -Dm644 "LICENSE" "${pkgdir}${MINGW_PREFIX}/share/licenses/${_realname}/LICENSE"
+    install -Dm644 "README.md" "${pkgdir}${MINGW_PREFIX}/share/doc/${_realname}/README.md"
+}