Merge pull request #9806 from raedrizqie/python-textdistance

New package: python-textdistance 4.2.1

mingw-w64-python-textdistance/PKGBUILD

@@ -0,0 +1,40 @@
+# Contributor: Raed Rizqie <raed.rizqie@gmail.com>
+
+_realname=textdistance
+pkgbase=mingw-w64-python-${_realname}
+pkgname=${MINGW_PACKAGE_PREFIX}-python-${_realname}
+pkgver=4.2.1
+pkgrel=1
+pkgdesc='Compute distance between sequences (mingw-w64)'
+arch=('any')
+mingw_arch=('mingw32' 'mingw64' 'ucrt64' 'clang64' 'clang32')
+license=('MIT')
+url='https://github.com/life4/textdistance'
+#depends=(
+#    ${MINGW_PACKAGE_PREFIX}-python-pywin32-ctypes)
+makedepends=(
+    ${MINGW_PACKAGE_PREFIX}-python
+    ${MINGW_PACKAGE_PREFIX}-python-setuptools)
+source=("https://github.com/life4/${_realname}/archive/v.${pkgver}.tar.gz")
+sha256sums=('2f475938edbef7faee50deeb000c81877e1165c29ff091b7c871dbcd0a244ca4')
+
+prepare() {
+  cd "${srcdir}"
+  rm -rf python-build-${CARCH} | true
+  cp -r "${_realname}-v.${pkgver}" "python-build-${CARCH}"
+}
+
+build() {
+  msg "Python build for ${CARCH}"
+  cd "${srcdir}/python-build-${CARCH}"
+  ${MINGW_PREFIX}/bin/python setup.py build
+}
+
+package() {
+  cd "${srcdir}/python-build-${CARCH}"
+  MSYS2_ARG_CONV_EXCL="--prefix=;--install-scripts=;--install-platlib=" \
+  ${MINGW_PREFIX}/bin/python setup.py install --prefix=${MINGW_PREFIX} \
+    --root="${pkgdir}" --optimize=1 --skip-build
+
+  install -Dm644 LICENSE "${pkgdir}${MINGW_PREFIX}/share/licenses/python-${_realname}/LICENSE"
+}